READ INPUT

+ >>>>>>>>>>
> +
[
	-
	>>>> ,
	[-<+<+>>]<<[->>+<<]
	+
	> +
	[
		[-]
		< -
		>>>>>>>> +

		<<<<< ,
		[->+>+<<]>>[-<<+>>]
		+
		< --------------------------------
		[>-<[-]]
		> [<<[-]>>[-]]
		< ,
		> ,
		[->+>+<<]>>[-<<+>>]
		+
		< --------------------------------
		[>-<[-]]
		> [<<[-]>>[-]]

		< ,
		>++++++[-<---------->]<-

		<<<<<
	]

	<
	[ >> [-] << [-] ]

	>>>>>>>>
]

<<<<<<<<<<

>+++++++[-<++++++++++++>]<- <
+
>>>>>> + <<<<<<


MAIN LOOP

>>++++++++[-<--------->]<
[
	>++++++++[-<+++++++++>]<<

	EXECUTION STEP

	>> +
	[
		- >>>>> +
		<[->->+<<]>>[-<<+>>]<
	]
	<<

	>>>> [-<+<+>>]<[->+<]
	+
	[
		-
		<<<<< +
		<<< [->>+>-<<<] >> [-<<+>>]
		>>>>> [-<<<<<+>>>>>] <<<<
	]

	<< [-<<<<<<<<<<+>>>>>>>>>> >>+<<] >>[-<<+>>]
	< [-<<<<<<<<<<+>>>>>>>>>>]
	> +
	[
		[-] <<<<<<<<<< [-]
		>> [-<+<+>>]<<[->>+<<]
		<< [-<+>>>+<<]<[->+<]
		>>> [->-<]>[<+>[-]]
		< [-<<<<<<<<<<+>>>>>>>>>>]

		>>> [-<<+<+>>>]<<<[->>>+<<<]
		< [-<<+>>>+<]<<[->>+<<]
		>>> [->-<]>[<+>[-]]
		< [-<<<<<<<<<+>>>>>>>>>]

		<<<<<<<<<< [->>>>>>>>>>>+<<<<<<<<<<<]
		> [->>>>>>>>>>+<<<<<<<<<<] >>>>>>>>>>
		[[-]<+>]

		< [-<<<+<<<<<<<+>>>>>>>>>>]<<<[->>>+<<<]

		<<<<<<<<<< [>>>>>>>>>> >>>[-]>+<<<< <<<<<<<<<<-]
		>>>>>>>>>> >>>> [-<<<< <<<<<<<<<<+>>>>>>>>>> >>>>]

		<<< [-<<<<<<<<<<+>>>>>>>>>>]
		> [-<<<<<<<<<<+>>>>>>>>>>]
		>
	]

	<<<<<<<<<<
	[$]  CRASH

	<< [-] > [-]
	>>>>>>>>>> >>>>> [-<<<<<+<+>>>>>>]<<<<<<[->>>>>>+<<<<<<]
	>>>>>>> [-<<<<<+<<+>>>>>>>]<<<<<<<[->>>>>>>+<<<<<<<]
	>>>>>>>> [-<<<<<+<<<+>>>>>>>>]<<<<<<<<[->>>>>>>>+<<<<<<<<]

	>>>>>>>>>>> +
	[
		<< [->>->+<<<] >>> [-<<<+>>>]
		< [->>>>>>>>>>+<<<<<<<<<<]
		<<<<<<<<<< [->>>>>>>>>>+<<<<<<<<<<]
		> [->>>>>>>>>>+<<<<<<<<<<]
		> [->>>>>>>>>>+<<<<<<<<<<]
		>>>>>>>> >>>>>>>>>>
	]

	<<<<<<<<<<

	< [-]
	> [-<+>]
	> [-<+>] > [-<+>]

	>>> +
	[
		< [->->+<<] >> [-<<+>>]
		< [->>>>>+<<<<<]
		<<<<< [->>>>>+<<<<<] > [->>>>>+<<<<<] >>>>
		>>>>>
	]

	<<<<<

	>> [-]
	<< [->>+<<]

	> [-<+<<+>>>] <<< [->>>+<<<]

	>>
	[
		-
		[<<+>>[-]]
	]

	>
	[
		+
		[<+>[-]]
	]

	<<<
	[
		<<<<<
		[$]  CRASH
		>>>>>> [-<<<<<+>>>>>]
		< [-]
	]

	>>
	[
		< [->>>>>+<<<<<]
		> [-]
	]

	+
	[
		-
		<<<<< +
		<< [->>->+<<<] >>> [-<<<+>>>]
		<
	]

	<<


	FINAL PART OF MAIN LOOP
	>>++++++++[-<--------->]<
]