0I[prints string; destructive]
F<strprint>[
	<strrev>
	28p
	SDW[
		D3RD3rM o D3rq
	D]
	PP
]

0I[gets last character of string; destructive]
F<strlast>[
	28pM
]

0I[drops last character of string; destructive]
F<strinit>[
	28pq
]

0I[takes string char; returns string+char]
F<strpush>[
	S28pma
]

0I[reverses string in place]
F<strrev>[
	0S
	DW[
		D 28p D 3r M 3r q 3r S 28p m a S
	D]
	P
]

0I[concatenates two strings]
F<strcat>[
	<strrev> 28p S
	DW[
		S D 3r S D 3R M 4R 28pma 3r S D 3r q
	D]
	PP
]

0I[takes list of characters and a length, builds a string]
F<mkstr>[
	0S
	DW[
		D2aR 3R 28p m a S d
	D]
	P
]

0I[compares two strings; 0 = equal, >0, <0 = second string is greater, less than first; destructive]
F<strcmp>[
	0 3r
	<dup2>mW[
		D28pM 3R D28pM S 4r S s
		DI[
			4rPPP00
			0  0I[to counter the P after the if]
		]
		P
		28pqS28pqS
	<dup2>m]
	PP
]

0I[takes string, returns integer (assumes correct input: only digits and at most
   one minus); replaces string on stack]
F<parseint>[
	<strrev>
	0 S
	DW[
		D 28pM
		D'-EI[P S 0Ss S 0]
		DI['0s 3R 9ima S 0]
		P 28pq
	D]
	P
]


0I[initialises variable store at beginning of stack (no args) (CALL ONLY ONCE)]
F<varinit>[
	0lr 0lr 0lr  0I[guard]
]

0I[hauls variable by name in argument to top of stack (result: name value);
   pushes 0 0 if non-existent]
F<varhaulup>[
	00  0I[guard]
	lRlR
	SD3rW[
		0I['s't'a'r't' 'w'h'i'l'e 9i 93a<mkstr><strprint>]
		SD3r
		6R  0I[get target varname up]
		D5r
		EDI[P
			0I['e'q'u'a'l'! 9i 7<mkstr><strprint>]
			D3r
			4RD5rW[
				4r4rlrlr
			4RD5r]
			3RP3RP
			0  0I[to stop while loop]
			1  0I[to prevent taking of the else branch]
		]
		nI[
			0I['u'n'e'q'u'a'l'! 9i 9<mkstr><strprint>]
			lRlR  0I[get next one]
			SD3r  0I[get name up; if zero, then while loop should stop: end of var list]
		]
	]
	0I['d'o'n'e' 'w'i't'h' 'w'h'i'l'e 9i  79a<mkstr><strprint>]
	SD3rnI[
		0I['i's' 'z'e'r'o 9i 8<mkstr><strprint>]
		lrlr3RP
		SD3rW[
			lrlr
		SD3r]
	]
	0I['d'o'n'e' 'w'i't'h' 'v'a'r'h'a'u'l'u'p 9i 99aii<mkstr><strprint>]
]

0I[pushes whether specified variable exists in store]
F<varexists>[
	<varhaulup>
	Pnn
]

0I[deletes variable given by argument from store]
F<vardel>[
	00  0I[guard]
	lRlR
	SD3rW[
		0I['s't'a'r't' 'w'h'i'l'e 9i 93a<mkstr><strprint>]
		SD3r
		6R  0I[get target varname up]
		D5r
		EDI[P
			0I['e'q'u'a'l'! 9i 7<mkstr><strprint>]
			PPP
			SD3rW[
				lrlr
			SD3r]
			PP
			1  0I[did find the thing]
			0  0I[to stop while loop]
			1  0I[to prevent taking of the else branch]
		]
		nI[
			0I['u'n'e'q'u'a'l'! 9i 9<mkstr><strprint>]
			lRlR  0I[get next one]
			SD3r  0I[get name up; if zero, then while loop should stop: end of var list]
		]
	]
	0I['d'o'n'e' 'w'i't'h' 'w'h'i'l'e 9i  79a<mkstr><strprint>]
	nI[
		0I['i's' 'z'e'r'o 9i 8<mkstr><strprint>]
		0lrlr3RP
		SD3rW[
			lrlr
		SD3r]
		PP
	]
	0I['d'o'n'e' 'w'i't'h' 'v'a'r'd'e'l 9i 89a<mkstr><strprint>]
]

0I[takes variable name (string) and value to store]
F<varstore>[
	0I['s't'o'r'i'n'g'  8<mkstr><strprint>
	   O
	   ' 'i'n'  4<mkstr><strprint>
	   <strprint>
	   9io
	  ]
	
	SD<vardel>
	Slrlr
]

0I[takes variable name (string) and pushes its value]
F<varget>[
	<varhaulup>
	SP
]


0I[takes socket and string; sends string to socket]
F<strsend>[
	<strrev>
	DW[D28pM3RSwS28pqD]P
]


0I[A B -> A B A B]
F<dup2>[
	SD3RD3r
]

0I[number -> n'th stack item from top (top is 1);
   a b c d e  4<sget>  -> a b c d e b]
F<sget>[iDRD3Rr]

0I[value, number -> replace n'th stack item AFTER value with value (top is 1);
   a b c d e  X 2<sput>  ->  a b c X e]
F<sput>[DiiRPr]

0I[quits program]
F<quit>[`]